Ferramentas do usuário

Ferramentas do site


tradingview:desenho:anotacoes_de_desenho

Anotaçoes de Desenho

Níveis de Preço (hline)

  • A anotação hline plota uma linha horizontal a um dado nível, por exemplo:
//@version=4
study(title="Chaikin Oscillator", shorttitle="Chaikin Osc")
short = input(3, minval=1)
long = input(10, minval=1)
osc = ema(accdist, short) - ema(accdist, long)
plot(osc, color=color.red)
hline(0, title="Zero", color=color.gray, linestyle=hline.style_dashed)
  • Um número deve ser atribuído ao primeiro argumento de hline.
  • Valores do tipo séries não são permitidos.
  • É possível criar múltiplas linhas horizontais com hline a preencher o fundo entre elas com uma transluscente usando fill.

Coloração de Fundo Plotagem (fill)

  • A anotação fill permite que o fundo seja colorido entre duas plotagens de séries ou duas plotagens de linhas horizontais criadas com a anotação hline.
//@version=4
study("fill Example")
p1 = plot(sin(high))
p2 = plot(cos(low))
p3 = plot(sin(close))
fill(p1, p3, color=color.red)
fill(p2, p3, color=color.blue)
h1 = hline(0)
h2 = hline(1.0)
h3 = hline(0.5)
h4 = hline(1.5)
fill(h1, h2, color=color.yellow)
fill(h3, h4, color=color.lime)
  • Note que a anotação fill não pode ser usada com as funções plot e hline como argumentos ao mesmo tempo.
  • Como alternativa é possível substituir hline com uma plot(<número constante>)
//@version=4
study("Fill example 2")
src = close, len = 10
ma = sma(src, len)
osc = 100 * (ma - src) / ma
p = plot(osc)
// NOTE: fill(p, hline(0)) wouldn't work, instead use this:
fill(p, plot(0))
  • Você pode configurar a cor do preenchimento usando
    • color=color.red
    • color=#FF001A
    • color = close >= open ? color.green : color.red
//@version=4
study(title="Colored fill")
line1=sma(close, 5)
line2=sma(close, 20)
p1 = plot(line1)
p2 = plot(line2)
fill(p1, p2, color = line1 > line2 ? color.green : color.red)

Coloração de Fundo Gráfico (bgcolor)

  • A anotação bgcolor muda a cor do fundo do gráfico onde o código está rodando, seja o gráfico principal ou uma nova janela.
  • A cor usada em bgcolor pode ser calculada em uma expressão e um parâmetro de transparência opcional transp permite controlar o nível de transparência.
    • Valores permitidos de 0 a 100
    • Valor padrão 90
//@version=4
study("bgcolor example", overlay=true)
timeinrange(res, sess) => time(res, sess) != 0
premarket = #0050FF
regular = #0000FF
postmarket = #5000FF
color notrading = na
sessioncolor = timeinrange("30", "0400-0930") ? premarket :
    timeinrange("30", "0930-1600") ? regular :
    timeinrange("30", "1600-2000") ? postmarket : notrading
bgcolor(sessioncolor, transp=75)

Coloração de Barra (barcolor)

  • A anotação barcolor permite colorir barras. A coloração pode ser condicional.
  • Valores na não alterar a cor da barra e deixam conforme o gráfico foi configurado.
  • Irá funcionar independente da configuração overlay.
//@version=4
study("barcolor example", overlay=true)
isUp() => close > open
isDown() => close <= open
isOutsideUp() => high > high[1] and low < low[1] and isUp()
isOutsideDown() => high > high[1] and low < low[1] and isDown()
isInside() => high < high[1] and low > low[1]
barcolor(isInside() ? color.yellow : isOutsideUp() ? color.aqua : isOutsideDown() ? color.purple : na)


tradingview/desenho/anotacoes_de_desenho.txt · Última modificação: 05/04/2023 08:25 por 127.0.0.1